lib-ld.m4 3.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119
  1. # lib-ld.m4 serial 6
  2. dnl Copyright (C) 1996-2003, 2009-2013 Free Software Foundation, Inc.
  3. dnl This file is free software; the Free Software Foundation
  4. dnl gives unlimited permission to copy and/or distribute it,
  5. dnl with or without modifications, as long as this notice is preserved.
  6. dnl Subroutines of libtool.m4,
  7. dnl with replacements s/_*LT_PATH/AC_LIB_PROG/ and s/lt_/acl_/ to avoid
  8. dnl collision with libtool.m4.
  9. dnl From libtool-2.4. Sets the variable with_gnu_ld to yes or no.
  10. AC_DEFUN([AC_LIB_PROG_LD_GNU],
  11. [AC_CACHE_CHECK([if the linker ($LD) is GNU ld], [acl_cv_prog_gnu_ld],
  12. [# I'd rather use --version here, but apparently some GNU lds only accept -v.
  13. case `$LD -v 2>&1 </dev/null` in
  14. *GNU* | *'with BFD'*)
  15. acl_cv_prog_gnu_ld=yes
  16. ;;
  17. *)
  18. acl_cv_prog_gnu_ld=no
  19. ;;
  20. esac])
  21. with_gnu_ld=$acl_cv_prog_gnu_ld
  22. ])
  23. dnl From libtool-2.4. Sets the variable LD.
  24. AC_DEFUN([AC_LIB_PROG_LD],
  25. [AC_REQUIRE([AC_PROG_CC])dnl
  26. AC_REQUIRE([AC_CANONICAL_HOST])dnl
  27. AC_ARG_WITH([gnu-ld],
  28. [AS_HELP_STRING([--with-gnu-ld],
  29. [assume the C compiler uses GNU ld [default=no]])],
  30. [test "$withval" = no || with_gnu_ld=yes],
  31. [with_gnu_ld=no])dnl
  32. # Prepare PATH_SEPARATOR.
  33. # The user is always right.
  34. if test "${PATH_SEPARATOR+set}" != set; then
  35. # Determine PATH_SEPARATOR by trying to find /bin/sh in a PATH which
  36. # contains only /bin. Note that ksh looks also at the FPATH variable,
  37. # so we have to set that as well for the test.
  38. PATH_SEPARATOR=:
  39. (PATH='/bin;/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
  40. && { (PATH='/bin:/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \
  41. || PATH_SEPARATOR=';'
  42. }
  43. fi
  44. ac_prog=ld
  45. if test "$GCC" = yes; then
  46. # Check if gcc -print-prog-name=ld gives a path.
  47. AC_MSG_CHECKING([for ld used by $CC])
  48. case $host in
  49. *-*-mingw*)
  50. # gcc leaves a trailing carriage return which upsets mingw
  51. ac_prog=`($CC -print-prog-name=ld) 2>&5 | tr -d '\015'` ;;
  52. *)
  53. ac_prog=`($CC -print-prog-name=ld) 2>&5` ;;
  54. esac
  55. case $ac_prog in
  56. # Accept absolute paths.
  57. [[\\/]]* | ?:[[\\/]]*)
  58. re_direlt='/[[^/]][[^/]]*/\.\./'
  59. # Canonicalize the pathname of ld
  60. ac_prog=`echo "$ac_prog"| sed 's%\\\\%/%g'`
  61. while echo "$ac_prog" | grep "$re_direlt" > /dev/null 2>&1; do
  62. ac_prog=`echo $ac_prog| sed "s%$re_direlt%/%"`
  63. done
  64. test -z "$LD" && LD="$ac_prog"
  65. ;;
  66. "")
  67. # If it fails, then pretend we aren't using GCC.
  68. ac_prog=ld
  69. ;;
  70. *)
  71. # If it is relative, then search for the first ld in PATH.
  72. with_gnu_ld=unknown
  73. ;;
  74. esac
  75. elif test "$with_gnu_ld" = yes; then
  76. AC_MSG_CHECKING([for GNU ld])
  77. else
  78. AC_MSG_CHECKING([for non-GNU ld])
  79. fi
  80. AC_CACHE_VAL([acl_cv_path_LD],
  81. [if test -z "$LD"; then
  82. acl_save_ifs="$IFS"; IFS=$PATH_SEPARATOR
  83. for ac_dir in $PATH; do
  84. IFS="$acl_save_ifs"
  85. test -z "$ac_dir" && ac_dir=.
  86. if test -f "$ac_dir/$ac_prog" || test -f "$ac_dir/$ac_prog$ac_exeext"; then
  87. acl_cv_path_LD="$ac_dir/$ac_prog"
  88. # Check to see if the program is GNU ld. I'd rather use --version,
  89. # but apparently some variants of GNU ld only accept -v.
  90. # Break only if it was the GNU/non-GNU ld that we prefer.
  91. case `"$acl_cv_path_LD" -v 2>&1 </dev/null` in
  92. *GNU* | *'with BFD'*)
  93. test "$with_gnu_ld" != no && break
  94. ;;
  95. *)
  96. test "$with_gnu_ld" != yes && break
  97. ;;
  98. esac
  99. fi
  100. done
  101. IFS="$acl_save_ifs"
  102. else
  103. acl_cv_path_LD="$LD" # Let the user override the test with a path.
  104. fi])
  105. LD="$acl_cv_path_LD"
  106. if test -n "$LD"; then
  107. AC_MSG_RESULT([$LD])
  108. else
  109. AC_MSG_RESULT([no])
  110. fi
  111. test -z "$LD" && AC_MSG_ERROR([no acceptable ld found in \$PATH])
  112. AC_LIB_PROG_LD_GNU
  113. ])